Autohotkey Date Parser

오늘은 Date 관련 함수를 하나 소개하려 합니다.

 

보통 Autohotkey 에서 Date 를 표현 할 때는 FormatTime 이라는 함수를 사용하는데요~

 

FormatTime 를 사용하면 YYYYMMDDHH24MISS format 으로 표현된 날짜 및 시간에 대해 다양한 형태로 표현 할 수 있습니다 .

 

하지만 FormatTime 함수에서는 문자 형식으로 표현된 날짜 즉… January, February, March, April, May, June, July, August, September, October, November, December 와 같이 문자로 표현된 날짜에 대해서는 변환 할 수가 없더군요.

 

그래서 좀 찾아보니 저만 불편해 한 게 아니었더군요.

 

아래 포럼에 polyethene 이라는 분이 Date Parser 를 만들어 놨더군요.

 

http://www.autohotkey.com/board/topic/18760-date-parser-convert-any-date-format-to-yyyymmddhh24miss/

 

위 주소에 들어가서~ 아래 그림과 같이 함수를 DateParse() 함수를 다운로드 받을 수 있습니다.

잘 못 찾으실 분들을 위해 파일도 올립니다. 

DateParse.ahk

 

위 그림의 예에서 보는 바와 같이 January 와 같이 달이 문자로 표현되고 시간이 AM, PM 과 같은 형태로 표현되도~ YYYYMMDDHH24MISS 형태로 parsing 할 수 있습니다.

 

저도 다운로드 받아서 아래와 같이 실행해 봤습니다.

 

/*

    Function: DateParse

        Converts almost any date format to a YYYYMMDDHH24MISS value.

 

    Parameters:

        str - a date/time stamp as a string

 

    Returns:

        A valid YYYYMMDDHH24MISS value which can be used by FormatTime, EnvAdd and other time commands.

 

    Example:

> time := DateParse("2:35 PM, 27 November, 2007")

 

    License:

        - Version 1.05 <http://www.autohotkey.net/~polyethene/#dateparse>

        - Dedicated to the public domain (CC0 1.0) <http://creativecommons.org/publicdomain/zero/1.0/>

*/

DateParse(str) {

    static e2 = "i)(?:(\d{1,2}+)[\s\.\-\/,]+)?(\d{1,2}|(?:Jan|Feb|Mar|Apr|May|Jun|Jul|Aug|Sep|Oct|Nov|Dec)\w*)[\s\.\-\/,]+(\d{2,4})"

    str := RegExReplace(str, "((?:" . SubStr(e2, 42, 47) . ")\w*)(\s*)(\d{1,2})\b", "$3$2$1", "", 1)

    If RegExMatch(str, "i)^\s*(?:(\d{4})([\s\-:\/])(\d{1,2})\2(\d{1,2}))?"

        . "(?:\s*[T\s](\d{1,2})([\s\-:\/])(\d{1,2})(?:\6(\d{1,2})\s*(?:(Z)|(\+|\-)?"

        . "(\d{1,2})\6(\d{1,2})(?:\6(\d{1,2}))?)?)?)?\s*$", i)

        d3 := i1, d2 := i3, d1 := i4, t1 := i5, t2 := i7, t3 := i8

    Else If !RegExMatch(str, "^\W*(\d{1,2}+)(\d{2})\W*$", t)

        RegExMatch(str, "i)(\d{1,2})\s*:\s*(\d{1,2})(?:\s*(\d{1,2}))?(?:\s*([ap]m))?", t)

            , RegExMatch(str, e2, d)

    f = %A_FormatFloat%

    SetFormat, Float, 02.0

    d := (d3 ? (StrLen(d3) = 2 ? 20 : "") . d3 : A_YYYY)

        . ((d2 := d2 + 0 ? d2 : (InStr(e2, SubStr(d2, 1, 3)) - 40) // 4 + 1.0) > 0

            ? d2 + 0.0 : A_MM) . ((d1 += 0.0) ? d1 : A_DD) . t1

            + (t1 = 12 ? t4 = "am" ? -12.0 : 0.0 : t4 = "am" ? 0.0 : 12.0) . t2 + 0.0 . t3 + 0.0

    SetFormat, Float, %f%

    Return, d

}

 

MsgBox % DateParse("2:35 PM, 27 jan, 2013")

 

이렇게~~ 201301271435 로 파싱이 되네요~ 이렇게 파싱만 되면 FormatTime 함수를 사용해서 얼마든지 변환 할 수 있겠죠~